ASP中class Property Get、Property Let 的簡(jiǎn)單介紹和使用方法

2011/7/8 11:14:02  出處：本站   人氣：108次    字號(hào)：小  中  大

本文將給大家一起分享介紹到的是關(guān)于ASP中class Property Get、Property Let 的簡(jiǎn)單介紹和使用方法，希望對(duì)大家有所幫助。

<%
'在 Class 塊中，成員通過(guò)相應(yīng)的聲明語(yǔ)句被聲明為 Private(私有成員，只能在類(lèi)內(nèi)部調(diào)用) 或 Public(公有成員，可以在類(lèi)內(nèi)外部調(diào)用) 。
'被聲明為 Private 的將只在 Class 塊內(nèi)是可見(jiàn)的。被聲明為 Public 不僅在 Class 塊的內(nèi)部是可見(jiàn)的，對(duì) Class 塊之外的代碼也是可見(jiàn)的。
'沒(méi)有使用 Private 或 Public 明確聲明的被默認(rèn)為 Public。在類(lèi)的塊內(nèi)部被聲明為 Public 的過(guò)程（Sub 或 Function）將成為類(lèi)的方法。
'Public 變量將成為類(lèi)的屬性，同使用 Property Get、Property Let 和 Property Set 顯式聲明的屬性一樣。
'類(lèi)的缺省屬性和方法是在它們的聲明部分用 Default 關(guān)鍵字指定的。
Class myClass
'//----聲明（聲明就是定義）myclass類(lèi)的類(lèi)內(nèi)部（私有的[Private]）變量
Private strAuthor
Private strVersion
Private strExample

'//---------------------------定義類(lèi)的事件-------------------------------//
'//----Class_Initialize()是類(lèi)的初始化事件，只要一開(kāi)始使用該類(lèi)，首先會(huì)觸發(fā)該部分的執(zhí)行.
'下面我們會(huì)在該成員中初始化該類(lèi)的作者和版本以在屏幕上顯示一下該類(lèi)已經(jīng)開(kāi)始了

Private Sub Class_Initialize()
strAuthor = "思源"
strVersion = "1.0"
Response.Write "<br/>myClass開(kāi)始了<br/>"
End Sub
'//----Class_Terminate()是類(lèi)的結(jié)束事件，只要一退出該類(lèi)，就會(huì)觸發(fā)該事件.
'下面我們會(huì)該事件中設(shè)定退出該類(lèi)時(shí)會(huì)在屏幕上顯示該類(lèi)已結(jié)束了。

Private Sub Class_Terminate()
Response.Write "<br/>myClass結(jié)束了<br/>"
End Sub

'//---------------------------用戶自己定義的方法-------------------------------//

'//----該方法返回一個(gè)版本信息

Public Sub Information()
Response.Write "<br/>Coding By <a href='mailto:coder@sinobe.com'>Maxid_Zen</a> @ <a href='http://www.design60s.com'>www.design60s.com</a>.<br/>"
End Sub

'//---------------------------定義類(lèi)的輸出屬性-------------------------------//

'//----定類(lèi)的屬性，該屬性是讓用戶初始化strExample變量

Public Property Let setExample(ByVal strVar)
strExample = strVar
End Property

'//---------------------------定義類(lèi)的輸出屬性-------------------------------//

'//----定義類(lèi)的屬性，該屬性是返回一個(gè)版本號(hào)

Public Property Get Version
Version = strVersion
End Property

'//----定義類(lèi)的屬性，該屬性是返回該類(lèi)的作者號(hào)

Public Property Get Author
Author = strAuthor
End Property

'//----定義類(lèi)的屬性，該屬性是返回用戶自定義信息

Public Property Get Example
Example = strExample
End Property


End Class
%>
<%

'//-------這里是使用該類(lèi)的例子

Dim oneNewClass

Set oneNewClass = new myClass

Response.Write "作者：" & oneNewClass.Author & "<br/>"
Response.Write "版本：" & oneNewClass.Version & "<br/>"

oneNewClass.setExample = "這是一個(gè)簡(jiǎn)單類(lèi)的例子"

Response.Write "用戶自定義：" & oneNewClass.Example & "<br/>"

oneNewClass.Information

Set oneNewClass = Nothing

%>

Property Get 語(yǔ)句
在 Class 塊中，聲明構(gòu)成用來(lái)取得（返回）的值的屬性過(guò)程的主體的名稱(chēng)、參數(shù)和代碼。

[Public [Default]| Private] Property Get name [(arglist)]
[statements]
[[Set] name = expression]
[Exit Property]
[statements]
[[Set] name = expression]
End Property

參數(shù)
Public

表明Property Get 過(guò)程可以被所有腳本中的其他過(guò)程訪問(wèn)。

Default

只與 Public 關(guān)鍵字一起使用，表明 Property Get 過(guò)程中定義的屬性為類(lèi)的缺省屬性。

Private

表明 Property Get 過(guò)程只對(duì)定義它的 Class 塊中的其他過(guò)程是可以訪問(wèn)的。

name

Property Get 過(guò)程的名稱(chēng)；遵守標(biāo)準(zhǔn)的變量命名規(guī)則，區(qū)別僅僅在于它可以與同一Class塊中的Property Let 或 Property Set過(guò)程。

arglist

該變量列表代表了 Property Get 過(guò)程被調(diào)用時(shí)傳遞給它的參數(shù)。多個(gè)參數(shù)之間用逗號(hào)分隔開(kāi)。Property Get 過(guò)程中的每個(gè)參數(shù)的名稱(chēng)必須與 Property Let 過(guò)程中的相應(yīng)參數(shù)相同(如果有的話)。

statements

任意的一組語(yǔ)句，將在 Property Get 過(guò)程的主體中執(zhí)行。

Set

在將對(duì)象作為 Property Get 過(guò)程的返回值時(shí)使用的關(guān)鍵字。

expression

Property Get 過(guò)程的返回值。

說(shuō)明
如果未使用 Public 或 Private明確聲明，則 Property Get 過(guò)程被缺省為公有的，即它們對(duì)于腳本中的其他所有過(guò)程都是可見(jiàn)的。Property Get過(guò)程中的局部變量的值在不同的過(guò)程調(diào)用之間是不保存的。

在其他任何過(guò)程(例如 Function 或 Property Let) 內(nèi)部都不能定義 Property Get 過(guò)程。

Exit Property 語(yǔ)句將導(dǎo)致立即從 Property Get 過(guò)程中退出。程序?qū)⒗^續(xù)執(zhí)行調(diào)用 Property Get 過(guò)程的語(yǔ)句之后的程序。Exit Property 語(yǔ)句可以出現(xiàn)在 Property Get 過(guò)程中的任何位置，次數(shù)不限。

與Sub 和 Property Let 過(guò)程類(lèi)似，Property Get 過(guò)程是能夠接受參數(shù)的過(guò)程，可以執(zhí)行一系列的語(yǔ)句，以及改變參數(shù)的值。然而，與Sub 和 Property Let 不同的是，Property Get 過(guò)程可以被用于表達(dá)式的右側(cè)，用與使用Function 或?qū)傩悦�稱(chēng)相同的方式來(lái)返回屬性的值。

Property Let 語(yǔ)句
在 Class 塊中，聲明名稱(chēng)、參數(shù)和代碼等，它們構(gòu)成了賦值（設(shè)置）的 Property 過(guò)程的主體。

[Public | Private] Property Let name (
[arglist,] value
)
[statement]
[Exit Property]
[statement]
End Property

參數(shù)
Public

表明 Property Let 過(guò)程可以被所有腳本中的其他所有過(guò)程訪問(wèn)。

Private

表明 Property Let 過(guò)程只能被定義之的 Class 塊內(nèi)的其他過(guò)程訪問(wèn)。

name

Property Let 過(guò)程的名稱(chēng)；遵守標(biāo)準(zhǔn)的變量命名規(guī)則，區(qū)別僅僅在于其名稱(chēng)可以與相同 Class 塊中的 Property Get 或 Property Set 過(guò)程相同。

arglist

該變量列表代表了在調(diào)用時(shí)被傳遞到 Property Let 過(guò)程的參數(shù)。多個(gè)參數(shù)之間用逗號(hào)隔開(kāi)。Property Let 過(guò)程的每個(gè)參數(shù)的名字必須與 Property Get 過(guò)程中的相應(yīng)參數(shù)相同。此外， Property Let 過(guò)程的參數(shù)比相應(yīng)的 Property Get 過(guò)程總要多一個(gè)。該參數(shù)為被賦予屬性的值。

value

該變量中包含要賦予屬性的值。當(dāng)過(guò)程被調(diào)用時(shí)，該參數(shù)將出現(xiàn)在調(diào)用表達(dá)式的右側(cè)。

statement

任意的一組語(yǔ)句，將在 Property Let 過(guò)程的主體內(nèi)執(zhí)行。

注意每個(gè) Property Let 語(yǔ)句必須為所定義的屬性定義至少一個(gè)參數(shù)。該參數(shù)（在存在多個(gè)參數(shù)時(shí)的最后一個(gè)參數(shù)）包含了當(dāng) Property Let 語(yǔ)句被調(diào)用時(shí)要賦予屬性的值。該參數(shù)在前面的語(yǔ)法中被稱(chēng)為value。

說(shuō)明
如果未明確地使用 Public 或 Private進(jìn)行指定，Property Let 過(guò)程被缺省設(shè)置為公有的，即它們對(duì)于腳本內(nèi)的其他所有過(guò)程都是可見(jiàn)的。Property Let過(guò)程中的局部變量的值在不同的過(guò)程調(diào)用之間是不被保存的。

在其他任何過(guò)程（例如 Function 或 Property Get）的內(nèi)部不能夠定義 Property Let 過(guò)程。

Exit Property 語(yǔ)句將導(dǎo)致立即從 Property Let 過(guò)程中退出。程序?qū)�從調(diào)用 Property Let 過(guò)程的語(yǔ)句之后的點(diǎn)繼續(xù)執(zhí)行。Exit Property 語(yǔ)句可以出現(xiàn)在 Property Let 過(guò)程中的任何位置，次數(shù)不限。

與 Function 和 Property Get 過(guò)程類(lèi)似，Property Let 過(guò)程是一個(gè)單獨(dú)的過(guò)程，它可以接受參數(shù)，執(zhí)行一系列的語(yǔ)句，還可以改變參數(shù)的值。不過(guò)，與Function 和 Property Get 過(guò)程不同的是，它們兩者都返回一個(gè)值，而Property Let過(guò)程只能用于屬性賦值表達(dá)式的左側(cè)。

Property Set 語(yǔ)句
在 Class 塊中，聲明名稱(chēng)、參數(shù)和代碼，這些構(gòu)成了將引用設(shè)置到對(duì)象的 Property 過(guò)程的主體。

[Public | Private] Property Set name(
[arglist,] reference
)
[statement]
[Exit Property]
[statement]
End Property

參數(shù)
Public

表明 Property Set 過(guò)程可以被所有腳本中的其他所有過(guò)程訪問(wèn)。

Private

表明 Property Set 過(guò)程只能被聲明之的同一 Class 塊中的其他過(guò)程訪問(wèn)。

name

Property Set 過(guò)程的名稱(chēng)；遵守標(biāo)準(zhǔn)的變量命名規(guī)則，不過(guò)該名稱(chēng)可以與同一個(gè) Class 塊中的 Property Get 或 Property Let 過(guò)程相同。

arglist

變量列表，代表在 Property Set 過(guò)程被調(diào)用時(shí)傳遞給它的參數(shù)。多個(gè)參數(shù)之間用逗號(hào)分隔開(kāi)。此外，Property Set 過(guò)程將總是比它相應(yīng)的 Property Get 過(guò)程多一個(gè)參數(shù)。這個(gè)多出來(lái)的參數(shù)是被賦予的對(duì)象。

reference

變量，其中包含被用于對(duì)象引用賦值的右側(cè)的對(duì)象引用。

statement

將要在 Property Set 過(guò)程主體中執(zhí)行的任何一組語(yǔ)句。

注意每個(gè) Property Set 語(yǔ)句都必須為所定義的過(guò)程定義至少一個(gè)參數(shù)。當(dāng) Property Set 語(yǔ)句所定義的過(guò)程被調(diào)用時(shí)，該必需參數(shù)（在多個(gè)參數(shù)時(shí)為最后一個(gè)參數(shù)）中將為屬性提供實(shí)際的對(duì)象引用。在前面的語(yǔ)法中，該參數(shù)被稱(chēng)為引用。

說(shuō)明
除非使用 Public 或 Private 明確地進(jìn)行指定，否則 Property Set 過(guò)程被設(shè)置為缺省的公有模式，即腳本中的其他所有過(guò)程都是可見(jiàn)的。在不同的過(guò)程調(diào)用時(shí)，Property Set 過(guò)程中的局部變量是不保存的。

在其他任何過(guò)程（例如Function或Property Let）中都不能夠定義Property Set過(guò)程。

Exit Property 語(yǔ)句將導(dǎo)致立即從 Property Set 過(guò)程中退出。程序?qū)⒗^續(xù)執(zhí)行調(diào)用 Property Set 過(guò)程之后的語(yǔ)句。Exit Property 語(yǔ)句的數(shù)量不受限制，可以出現(xiàn)在 Property Set 過(guò)程中的任何位置。

與 Function 和 Property Get 過(guò)程類(lèi)似，Property Set 過(guò)程是一個(gè)單獨(dú)的過(guò)程，它可以有若干參數(shù)，執(zhí)行一系列的語(yǔ)句，還可以改變參數(shù)的值。然而，與 Function 和 Property Get 過(guò)程不同的是，函數(shù)和過(guò)程都可以返回值，而 Property Set 過(guò)程對(duì)象引用賦值（Set 語(yǔ)句）的左側(cè)。